لاقط شاشة سهل الإستخدام و صغير الحجم

    • لاقط شاشة سهل الإستخدام و صغير الحجم

      تعديل بسيط على البرنامج تم التعديل على المرفق
      تعليمات الإستخدام
      HotKeySet("{PRINTSCREEN}", "ChildWindowsCapture")
      HotKeySet("{ESC}", "Terminate")
      HotKeySet("{HOME}", "AllChildWindowsCapture")0

      بعد تشغل البرنامج مباشرة يقوم بعمل منجل على النافذة و التي في مقدمة الشاشة
      للتقاطها تظغط على مفتاح PRINTSCREEN في لوحة المفاتيح يمكنك
      تمرير الماوس لتحديد جزء من برنامج أو نافذة كلأزرار أو القوائم ثم تضغط
      على نفس المفتاح ستجد الصورة الملتقطة بداخل مجلد جديد اسمه Capture
      و موقعه بجانب البرنامج

      يمكنك أخذ جميع النوافذ المتاحة لبرنامج على مقدمة الشاشة بالضغط على مفتاح
      HOME بلوحة المفاتيح حيث سيتم أخذ صور لجميع الأزرة و القوائم و أدوات
      التحكم للبرنامج ستجد الصور الملتقطة بجنب البرنامج في مجلد اسمه AllCapture

      لإقفال البرنامج قم بالضغط على مفتاح الهروب أو الخروج Esc في الزاوية اليسرى
      العلوية للوحة المفاتيح .

      الصور الملتقطة بنوعين PNG و BMP

      البرنامج على المرفقات

      كود البرنامج على لغة Autoit لمن يريد الإستفاده منه .... في حفض الله

      أعتذر سبق و عرضت سكاربت البرنامج على كود PHP
      و حدثت أخطاء في السكاربت بعض الشرط إنحذفت بسبب أن أوامر
      هذه اللغة لا تتناسب مع هذا النوع من الكود و أرجو كذالك أن لا
      تكون هناك أخطاء بالمواضيع الأخرى الآن قمت باستخدام الكود
      العادي و الأوامر كاملة وصحيحة .

      C كود المصدر

      1. #include <WindowsConstants.au3>
      2. #include <GDIPlus.au3>
      3. #include <WinAPI.au3>
      4. #include <WindowsConstants.au3>
      5. #include <StructureConstants.au3>
      6. #include <ScreenCapture.au3>
      7. Global $Child = "" ,$ChildArray[1][5] , $PTR_Chi , $WINhwnd , _
      8. $hPen , $ForegroundX , $Capture , $CHK
      9. HotKeySet("{PRINTSCREEN}", "ChildWindowsCapture")
      10. HotKeySet("{ESC}", "Terminate")
      11. HotKeySet("{HOME}", "AllChildWindowsCapture")
      12. $hPen = _WinAPI_CreatePen($PS_SOLID,5,0xFF)
      13. While 1
      14. GetWindowsMose()
      15. WEnd
      17. Func AllChildWindowsCapture()
      18. DirCreate(@ScriptDir & "\AllCapture")
      19. $WindowArray = GetChildWindows(_WinAPI_GetForegroundWindow())
      20. _GDIPlus_Startup ()
      21. For $i = 0 To UBound($WindowArray) - 1
      22. _WinAPI_RedrawWindow($WindowArray[$i][0], 0, 0, $RDW_INVALIDATE + $RDW_ALLCHILDREN)
      23. $hBitmap = BitmapCreateFromControlHWND($WindowArray[$i][0])
      24. $hBitmap = _GDIPlus_BitmapCreateFromHBITMAP ($hBitmap)
      25. _GDIPlus_ImageSaveToFile ($hBitmap, @ScriptDir & "\AllCapture\" & $WindowArray[$i][0] & ".bmp")
      26. _GDIPlus_ImageSaveToFile ($hBitmap, @ScriptDir & "\AllCapture\" & $WindowArray[$i][0] & ".png")
      27. _WinAPI_DeleteObject ($hBitmap)
      28. Next
      29. _GDIPlus_ShutDown ()
      30. EndFunc
      32. Func GetWindowsMose()
      33. $pos = MouseGetPos()
      34. $Foreground = _WinAPI_GetForegroundWindow()
      35. $ChildArray = GetChildWindows($Foreground)
      36. _WinAPI_RedrawWindow($ForegroundX, 0, 0, $RDW_INVALIDATE + $RDW_ALLCHILDREN)
      37. Sleep(500)
      38. if IsArray($pos) And IsArray($ChildArray) Then
      39. $CHK = False
      40. For $i = 0 To UBound($ChildArray) - 1
      41. $ML = $pos[0]
      42. $MT = $pos[1]
      43. $hwnd = $ChildArray[$i][0]
      44. $L = $ChildArray[$i][1]
      45. $T = $ChildArray[$i][2]
      46. $W = $ChildArray[$i][3]
      47. $H = $ChildArray[$i][4]
      48. if ($ML >= $L ) And ($ML <= ($L + $W)) _
      49. And ($MT >= $T ) And ($MT <= ($T + $H)) Then
      50. $WINhwnd = $hwnd
      51. $LX = $L
      52. $TX = $T
      53. $WX = $W
      54. $HX = $H
      55. $CHK = True
      56. $ForegroundX = $Foreground
      57. $Capture = $WINhwnd
      58. EndIf
      59. Next
      60. IF $CHK = True And ($WINhwnd) Then
      61. $hDC = _WinAPIGetDC($WINhwnd)
      62. $obj_orig = _WinAPI_SelectObject($hDC, $hPen)
      63. _WinAPI_DrawLine($hDC,0,0,$WX,0)
      64. _WinAPI_DrawLine($hDC,0,0,0,$HX)
      65. _WinAPI_SelectObject($hDC, $obj_orig)
      66. Sleep(300)
      67. Else
      68. $RECT = _WinAPI_GetWindowRect($Foreground)
      69. $Capture = $Foreground
      70. $Desktop = _WinAPI_GetDesktopWindow()
      71. if ($Desktop) Then
      72. $hDC = _WinAPI_GetWindowDC($Desktop)
      73. $obj_orig = _WinAPI_SelectObject($hDC, $hPen)
      74. $Left = DllStructGetData($RECT,1)
      75. $Top = DllStructGetData($RECT,2)
      76. $Right = DllStructGetData($RECT,3)
      77. $Bottom = DllStructGetData($RECT,4)
      78. $L = $Left
      79. $T = $Top
      80. $W = $Right - $Left
      81. $H = $Bottom - $Top
      82. if $Left < 0 Then $Left = 0
      83. if $Right < 0 Then $Right = _WinAPI_GetSystemMetrics(0)
      84. if $Top < 0 Then $Top = 0
      85. if $Bottom < 0 Then $Bottom = _WinAPI_GetSystemMetrics(1)
      86. _WinAPI_DrawLine($hDC,$Left,$Top,$Right,$Top)
      87. _WinAPI_DrawLine($hDC,$Right,$Top,$Right,$Bottom)
      88. _WinAPI_SelectObject($hDC, $obj_orig)
      89. Sleep(300)
      90. $ForegroundX = $Desktop
      91. EndIf
      92. EndIf
      93. EndIf
      94. EndFunc
      97. Func ChildWindowsCapture()
      98. DirCreate(@ScriptDir & "\Capture")
      99. _WinAPI_RedrawWindow($Capture, 0, 0, $RDW_INVALIDATE + $RDW_ALLCHILDREN)
      100. if $CHK = True Then
      101. $hBitmap = BitmapCreateFromControlHWND($Capture)
      102. _GDIPlus_Startup ()
      103. $hBitmap = _GDIPlus_BitmapCreateFromHBITMAP ($hBitmap)
      104. _GDIPlus_ImageSaveToFile ($hBitmap, @ScriptDir & "\Capture\" & $WINhwnd & ".bmp")
      105. _GDIPlus_ImageSaveToFile ($hBitmap, @ScriptDir & "\Capture\" & $WINhwnd & ".png")
      106. _WinAPI_DeleteObject ($hBitmap)
      107. _GDIPlus_Shutdown ()
      108. Else
      109. _ScreenCapture_CaptureWnd(@ScriptDir & "\Capture\" & $WINhwnd & ".bmp",$Capture)
      110. _ScreenCapture_CaptureWnd(@ScriptDir & "\Capture\" & $WINhwnd & ".png",$Capture)
      111. EndIf
      112. EndFunc
      115. Func GetChildWindows($hWndParent)
      116. If Not ($PTR_Chi) Then $PTR_Chi = RegisterEnumChildProc("CALLBACK_EnumChildProc")
      117. EnumChildWindows($hWndParent , $PTR_Chi)
      118. if UBound($ChildArray) > 1 Then _
      119. ReDim $ChildArray[UBound($ChildArray) - 1][5]
      120. Return $ChildArray
      121. EndFunc
      123. Func EnumChildWindows($hWndParent , $lpEnumFunc)
      124. Local $lParam = 0
      125. Global $Child = ""
      126. Global $ChildArray = 0
      127. Dim $ChildArray[1][5]
      128. $BOOL = DllCall("user32.dll","int","EnumChildWindows","hwnd",$hWndParent,"ptr",$lpEnumFunc,"int",$lParam)
      129. if Not @error Then Return SetError(@error,"",$BOOL[0])
      130. Return SetError(@error,"",False)
      131. EndFunc
      133. Func RegisterEnumChildProc($lpEnumFunc)
      134. $handle = DLLCallbackRegister ($lpEnumFunc, "int", "hwnd;int")
      135. Return DllCallbackGetPtr($handle)
      136. EndFunc
      139. Func CALLBACK_EnumChildProc($hwnd,$lParam)
      140. $Test = False
      141. For $i = 0 To UBound($ChildArray) - 1
      142. if $hwnd = $ChildArray[$i][0] Then $Test = True
      143. Next
      144. if $Test = False Then
      145. $RECT = _WinAPI_GetWindowRect($hWnd)
      146. $Left = DllStructGetData($RECT,1)
      147. $Top = DllStructGetData($RECT,2)
      148. $Right = DllStructGetData($RECT,3)
      149. $Bottom = DllStructGetData($RECT,4)
      150. $L = $Left
      151. $T = $Top
      152. $W = $Right - $Left
      153. $H = $Bottom - $Top
      154. $ChildArray[UBound($ChildArray) - 1][0] = $hwnd
      155. $ChildArray[UBound($ChildArray) - 1][1] = $L
      156. $ChildArray[UBound($ChildArray) - 1][2] = $T
      157. $ChildArray[UBound($ChildArray) - 1][3] = $W
      158. $ChildArray[UBound($ChildArray) - 1][4] = $H
      159. ReDim $ChildArray[UBound($ChildArray) + 1][5]
      160. Return True
      161. Else
      162. Return False
      163. EndIf
      164. EndFunc
      167. Func BitmapCreateFromControlHWND($HWND)
      168. Local $Width = _WinAPI_GetWindowWidth($hWnd)
      169. Local $Height =_WinAPI_GetWindowHeight($hWnd)
      170. $DC = _WinAPIGetDC($HWND)
      171. $CompatibleDC = _WinAPI_CreateCompatibleDC($DC)
      172. $hBitmap = _WinAPI_CreateCompatibleBitmap($DC,$Width, $Height)
      173. _WinAPI_SelectObject($CompatibleDC, $hBitmap)
      174. _WinAPI_BitBlt($CompatibleDC, 0, 0, $Width, $Height, $DC, 0, 0,$SRCCOPY)
      175. Return $hBitmap
      176. EndFunc
      178. Func _WinAPIGetDC($hWnd)
      179. Local $aResult
      180. $aResult = DllCall("User32.dll", "hwnd", "GetDC", "hwnd", $hWnd)
      181. if Not @error Then Return $aResult[0]
      182. Return 0
      183. EndFunc ;==>_WinAPIGetDC
      186. Func Terminate()
      187. _WinAPI_RedrawWindow($Capture, 0, 0, $RDW_INVALIDATE + $RDW_ALLCHILDREN)
      188. Exit 0
      189. EndFunc
      عرض الكل

    • شكرا لك اخي ناقوس
      فقط حبيت استفسر، هل هناك فرق بين هذا البرنامج وبين الطريقة العايدة لتصوير الشاشة من الكيبورد؟
      ،،،
      أنت اليوم حيث أتت أفكارك وستكون غدا حيث تأخذك أفكارك

    • AL~FaReS كتب:

      شكرا لك اخي ناقوس
      فقط حبيت استفسر، هل هناك فرق بين هذا البرنامج وبين الطريقة العايدة لتصوير الشاشة من الكيبورد؟
      ،،،


      مرحبا الفارس ... هناك فرق بالطبع لأن التصوير عن طريق الكيبورد باستخدام مفتاح
      PRINTSCREEN يصور الشاشة كاملة أما عن طريق البرنامج فيمكن تصوير
      النوافذ الأبناء Child Windows لنافذة الأم و هي طبعا عبارة عن مقاطع
      من النافذة مثل الأزرة و القوائم العلاقة بين الطريقتين هي فقط في استخدام نفس
      مفتاح الكيبورد       PRINTSCREEN

      في حفض الله

    • [B]مشكور مشكور
      مشكور مشكور مشكور
      مشكور مشكور مشكور مشكور
      مشكور مشكور مشكور مشكور مشكور
      مشكور مشكور مشكور مشكور مشكور مشكور
      مشكور مشكور مشكور مشكور مشكور مشكور مشكور
      مشكور مشكور مشكور مشكور مشكور مشكور مشكور مشكور
      مشكور مشكور مشكور مشكور مشكور مشكور مشكور
      مشكور مشكور مشكور مشكور مشكور مشكور
      مشكور مشكور مشكور مشكور مشكور
      مشكور مشكور مشكور مشكور
      مشكور مشكور مشكور
      مشكور مشكور
      مشكور

      [/B]
      قال رسول الله صلى الله عليه وسلم من دخل الســــوق فقــــــال : لا إله إالا الله وحده لا شريك له له الملك وله الحمد يحيى ويميت وهو حى لا يموت بيده الخير وهو على كل شيء قدير. كتب له ألف ألف حسنة ومحــــــا عنه ألف ألف سيئـــة ورفــــــع لـــه ألف ألف درجــــــــــــة